# Maintainer: Gilles Gagniard <gilles@gagniard.org>

pkgname=simutrans
pkgver=99.13
_pkgver=$(echo $pkgver | tr . -)
pkgrel=1
pkgdesc="Simutrans is a freeware transportation simulator."
arch=('i686' 'x86_64')
url="http://www.simutrans.com"
license=('GPL')
depends=('zlib' 'libpng' 'sdl' 'sdl_mixer')
source=(
        "http://www.gagniard.org/gilles/arch/${pkgname}/${pkgname}-r1181.tar.bz2"
        "http://64.simutrans.com/simupak64-${_pkgver}.zip"
        "http://www.gagniard.org/gilles/arch/${pkgname}/fix_x64.patch"
        "http://www.gagniard.org/gilles/arch/${pkgname}/${pkgname}.desktop"
        "http://www.gagniard.org/gilles/arch/${pkgname}/${pkgname}.png"
)
md5sums=(
            'a573beacd3472c4bfa05796fedb8e9b1'
            '4aa729ae6fdab6d4e30cef73d2775547'
            'd12e310e0b09b2a9e183e6034264cabf'
            'e503704fabb228125c00d86bd56dfe70'
            '7b69608dd812e8bed284b10984c6170e'
)

build() {
  cd $startdir/src/${pkgname}-src

  if [ ${CARCH} = "x86_64" ]; then
      patch -p1 -i $startdir/src/fix_x64.patch || return 1
  fi

  cp config.template config.default
  sed \
    -e 's/#\(BACKEND = sdl\)/\1/' \
    -e 's/#\(COLOUR_DEPTH = 16\)/\1/' \
    -e 's/#\(OPTIMISE = 1\)/\1/' \
    -e 's/#\(SDL_CONFIG = sdl-config\)/\1/' \
    -e 's/#\(OSTYPE = linux\)/\1/' \
    -i config.default || return 1

  make || return 1

  mkdir -p ${startdir}/pkg/usr/share
  cp -r ${startdir}/src/${pkgname} ${startdir}/pkg/usr/share
  install -D -m 755 ${startdir}/src/${pkgname}-src/sim ${startdir}/pkg/usr/share/${pkgname}/${pkgname}
  mkdir -p ${startdir}/pkg/usr/bin
  ln -s /usr/share/${pkgname}/${pkgname} ${startdir}/pkg/usr/bin/${pkgname}

  install -D -m 644 ${startdir}/src/${pkgname}.desktop ${startdir}/pkg/usr/share/applications/${pkgname}.desktop
  install -D -m 644 ${startdir}/src/${pkgname}.png ${startdir}/pkg/usr/share/pixmaps/${pkgname}.png
}

# History:
#   99.13-1 : version bump
#             new patch as some fixes have been included upstream but new regressions have been introduced ...
#             sources are copied from official repository in order to not hammer it. no 'official' tarball yet.
#             add desktop shortcut
#   99.12-4 : reupload since the patch was broken
#   99.12-3 : don't force gcc to version 3 on linux32 since we already have a patch for that
#   99.12-2 : nicer script
#   99.12-1 : initial release