pkgname=bin32-true-combat
pkgver=0.49b
pkgrel=1
pkgdesc="True Combat: Elite (TCE) is a completely free, realistic, team-based modification for Enemy Territory."
url="http://www.truecombatelite.com/"
arch=('x86_64')
license=('custom')
depends=('bin32-enemy-territory' 'lib32-libstdc++5')
makedepends=('unzip')
conflicts=('true-combat')
backup=('opt/bin32-enemy-territory/tcetest/server.cfg')
install=
source=('http://www.gagniard.org/gilles/arch/bin32-true-combat/true-combat.desktop' \
'http://www.gagniard.org/gilles/arch/bin32-true-combat/true-combat.sh' \
'http://www.gagniard.org/gilles/arch/bin32-true-combat/true-combatded.sh' \
'http://dragons-perch.net/tce/tcetest049.zip' \
'http://dragons-perch.net/tce/tce049b_all_os_fixed.zip')
md5sums=('7100aaf825e599753b8a3b55628e8e78' '0c030edd8d56fb8db5d0cfd954cfcae9'\
         '8372221f7fc97496e67c5b3688098503' '996ef2743e36103a351199f3fd72e70f'\
         'ed09515b41a4af92740c42c3053225a9')

build() {
    cd $startdir/src

    # Unpack 0.49b Patch into 0.49 directory
    unzip -o $startdir/src/tce049b_all_os_fixed.zip -d $startdir/src/tcetest/

    # Remove Unneeded Files and Directories
    rm $startdir/src/tcetest/._Mac_users_run_me_first.pkg
    rm $startdir/src/tcetest/Mac\ Users\ Read\ Me\ First\ -\ Important\ Information.txt
    rm $startdir/src/tcetest/{cgame_mac,cgame_mp_x86.dll,qagame_mp_x86.dll,ui_mac,ui_mp_x86.dll}
    rm -r $startdir/src/tcetest/{Mac_users_run_me_first.pkg/,qagame_mac.bundle/}

    # Install License
    install -d $startdir/pkg/usr/share/licenses/$pkgname
    mv $startdir/src/tcetest/EULA_TrueCombat_Elite.txt \
        $startdir/pkg/usr/share/licenses/$pkgname/

    # Copy Data to Package Directory
    install -d $startdir/pkg/opt/bin32-enemy-territory/
    mv $startdir/src/tcetest $startdir/pkg/opt/bin32-enemy-territory/

    # Install Client Launcher Script 
    install -D -m 755 true-combat.sh \
        $startdir/pkg/usr/bin/true-combat

    # Install Server Launcher Script
    install -D -m 755 true-combatded.sh \
        $startdir/pkg/usr/bin/true-combatded

    # Install Icon File
    install -D -m 644 $startdir/pkg/opt/bin32-enemy-territory/tcetest/tce_icon_pc.ico \
        $startdir/pkg/usr/share/pixmaps/true-combat.ico

    # Install Desktop File
    install -D -m 644 true-combat.desktop \
        $startdir/pkg/usr/share/applications/true-combat.desktop
}