pkgname=bin32-enemy-territory
_pkgname=enemy-territory
pkgver=2.60b
pkgrel=1
pkgdesc="Wolfenstein: Enemy Territory is a completely free, standalone, team-based, multiplayer FPS."
url="http://www.castlewolfenstein.com/"
license="custom"
arch=('x86_64')
depends=('lib32-libgl' 'lib32-libxext')
conflicts=('enemy-territory')
makedepends=('unzip')
backup=(opt/$pkgname/etmain/server.cfg \
opt/$pkgname/etmain/punkbuster.cfg)
source=(http://ftp.games.skynet.be/pub/wolfenstein/et-linux-2.60.x86.run \
http://ftp.gwdg.de/pub/misc/ftp.idsoftware.com/idstuff/et/ET-$pkgver.zip \
http://www.gagniard.org/gilles/arch/bin32-enemy-territory/${_pkgname}.desktop \
http://www.gagniard.org/gilles/arch/bin32-enemy-territory/et-ded \
http://www.gagniard.org/gilles/arch/bin32-enemy-territory/et-pbupdate.sh \
http://www.gagniard.org/gilles/arch/bin32-enemy-territory/et.sh \
http://www.gagniard.org/gilles/arch/bin32-enemy-territory/etded.sh)
md5sums=('2d2373f29f02e18d365d7f1860eee435' 'fb83b8732fc7373c277180b663debf57'\
         'c0f9fc3f6d77814dae435be2aa42c46e' '6d8223ba6886b70025a6d8ea9a238c4a'\
         '31da07f53704d79e5084d4e0df31f38b' '81ddf3881a5cd29788e63f0a9a25aea0'\
         '8f012a45d0122c7fca52384a6015ec27')
install=${_pkgname}.install

build() {
  cd $startdir/src

  # Make Loki installer executable
  chmod +x et-linux-2.60.x86.run

  # Extract data from installer
  ./et-linux-2.60.x86.run --noexec --target $pkgname

  # Remove unnecessary files
  rm -r $pkgname/bin $pkgname/setup.{data,sh} $pkgname/README

  # Copy game EULA to main directory
  cp $pkgname/Docs/EULA_Wolfenstein_Enemy_Territory.txt $pkgname

  # Place scripts in main directory
  install -D -m755 et.sh $pkgname/et
  install -D -m755 etded.sh $pkgname/etded

  # Apply patched executables
  cp Enemy\ Territory\ $pkgver/linux/{et,etded}.x86 $pkgname

  # Make PunkBuster updater utility executable
  chmod +x $pkgname/pb/pbweb.x86

  # Make directories for PunkBuster with necessary permissions to
  # work with games user and group
  install -d -m2775 -o 50 -g games $pkgname/pb $pkgname/pb/{dll,htm,svlogs,svss}

  # Install licenses
  install -D -m644 $pkgname/EULA_Wolfenstein_Enemy_Territory.txt \
$startdir/pkg/usr/share/licenses/$pkgname/EULA_Wolfenstein_Enemy_Territory.txt
  install -D -m644 $pkgname/pb/PB_EULA.txt $startdir/pkg/usr/share/licenses/$pkgname/PB_EULA.txt

  # Make directories and move game data
  install -d $startdir/pkg/{opt,usr/bin}
  install -d -o 50 $startdir/pkg/home/games $startdir/pkg/home/games/etwolf-homedir
  mv $pkgname $startdir/pkg/opt

  # Install PunkBuster updater script
  install -D -m755 et-pbupdate.sh $startdir/pkg/usr/sbin/et-pbupdate

  # Install rc.d script
  install -D -m755 et-ded $startdir/pkg/etc/rc.d/et-ded

  # Install desktop file and icon
  install -D -m644 ${_pkgname}.desktop $startdir/pkg/usr/share/applications/${_pkgname}.desktop
  install -D -m644 $startdir/pkg/opt/$pkgname/ET.xpm \
$startdir/pkg/usr/share/pixmaps/${_pkgname}.xpm

  # Make symlink to pb directory for games user
  ln -sf /opt/enemy-territory/pb $startdir/pkg/home/games/etwolf-homedir

  # Make games .etwolf directory a symlink to etwolf-homedir
  ln -sf /home/games/etwolf-homedir $startdir/pkg/home/games/.etwolf

  # Make symlinks to main scripts
  ln -sf /opt/$pkgname/et $startdir/pkg/usr/bin/${_pkgname}
  ln -sf /opt/$pkgname/etded $startdir/pkg/usr/bin/${_pkgname}d
}